question

Alexander Farber avatar image
Alexander Farber asked

App submissions rejected, but no logs or device infos available for me

Hello fellow developers and dear Amazon employees!


Since over a year I have a multiplayer word game published at https://www.amazon.de/dp/B0792GQQZR/#ace-7038974143


Now I have translated it to English and German languages, but have problems getting it through the Amazon Appstore review.


The response is always the same: "The app exits/ force closes/ freezes/ displays an error message after being launched."


But there is no information on which device it was tested (on my Fire 5 and Fire 7 tablets the game runs just fine) and there is no error log.


I have tried contacting developer support asking for any logs, but got no response.


My app uses LWA and ADM and is minSdk 16. My app is also published at Google Store (it uses FCM there) and Huawei AppGallery (it uses HMS there).


I just need a little more information to fix any problems with my app. If I knew which device is being used for testing, I would just buy or loan it.


Is anyone maybe willing to sideload the APK files and give my game a try at her or his Fire devices?

https://wordsbyfarber.com/android/

https://wortefarbers.de/android/


Finally, below is my app/build.gradle - maybe someone can spot a problem with it?

apply plugin: 'com.android.application'

android {
    compileSdkVersion 29
    defaultConfig {
        versionCode 168
        targetSdkVersion 29
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        vectorDrawables.useSupportLibrary = true
        multiDexEnabled true

        javaCompileOptions {
            annotationProcessorOptions {
                arguments = ["room.schemaLocation": "$projectDir/schemas".toString()]
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    signingConfigs {
        debug {
            keyAlias 'AndroidDebugKey'
            storeFile file('../../../../../.android/debug.keystore')
            keyPassword 'android'
            storePassword 'android'
        }
        release {
            keyAlias 'AndroidReleaseKey'
            storeFile file('../../../conf/release.keystore')
            keyPassword System.getenv('PASSPHRASE1')
            storePassword System.getenv('PASSPHRASE1')
        }
    }

    flavorDimensions "store", "language"
    productFlavors {
        google {
            dimension "store"
            versionName "$defaultConfig.versionCode-google"
            // min sdk version 16 needed for Firebase messaging
            minSdkVersion 16
        }
        huawei {
            dimension "store"
            versionName "$defaultConfig.versionCode-huawei"
            // min sdk version 17 needed for Huawei push
            minSdkVersion 17
            applicationIdSuffix ".huawei"
            resConfigs "en", "zh-rCN", "ru", "de", "fr", "pl", "nl"
        }
        amazon {
            dimension "store"
            versionName "$defaultConfig.versionCode-amazon"
            // min sdk version 15 needed for older Amazon Fire models, but is no more supported by the LWA
            minSdkVersion 16
            // ignore AdmService not extending android.app.Service
            lintOptions {
                checkReleaseBuilds false
            }
        }

        de {
            applicationId "de.wortefarbers"
            dimension "language"
            resConfigs "de"
        }
        en {
            applicationId "com.wordsbyfarber"
            dimension "language"
            resConfigs "en"
        }
        ru {
            applicationId "de.slova"
            dimension "language"
            resConfigs "ru"
        }
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release
            debuggable false
            shrinkResources true
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation 'androidx.multidex:multidex:2.0.1'

    // minSdkVersion 9 is only supported by the OkHttp 3.12.x branch
    implementation 'com.squareup.okhttp3:okhttp:3.12.2'
    implementation 'com.squareup.picasso:picasso:2.71828'
    implementation 'com.neovisionaries:nv-websocket-client:2.10'

    implementation "androidx.room:room-common:$roomVersion"
    implementation "androidx.room:room-runtime:$roomVersion"
    annotationProcessor "androidx.room:room-compiler:$roomVersion"
    androidTestImplementation "androidx.room:room-testing:$roomVersion"

    implementation "androidx.lifecycle:lifecycle-extensions:$archVersion"
    annotationProcessor "androidx.lifecycle:lifecycle-common-java8:$archVersion"

    implementation 'androidx.cardview:cardview:1.0.0'
    implementation 'androidx.viewpager2:viewpager2:1.0.0'
    implementation 'com.google.android.material:material:1.3.0-alpha02'

    implementation 'me.zhanghai.android.materialprogressbar:library:1.6.1'
    implementation 'com.mikepenz:materialdrawer:6.1.2'
    implementation 'com.mikepenz:iconics-core:3.2.5'
    implementation 'com.mikepenz:fontawesome-typeface:5.3.1.1@aar'
    implementation 'com.github.PhilJay:MPAndroidChart:v3.1.0-alpha'
    implementation "com.facebook.android:facebook-core:$facebookVersion"
    implementation "com.facebook.android:facebook-login:$facebookVersion"

    googleImplementation 'com.google.android.gms:play-services-auth:18.1.0'
    googleImplementation 'com.google.firebase:firebase-messaging:20.2.4'
    googleImplementation 'com.android.billingclient:billing:3.0.0'

    huaweiImplementation "com.huawei.hms:base:$hmsVersion"
    huaweiImplementation "com.huawei.hms:hwid:$hmsVersion"
    huaweiImplementation "com.huawei.hms:push:$hmsVersion"
    huaweiImplementation "com.huawei.hms:iap:$hmsVersion"

    amazonCompileOnly files('libs/amazon-device-messaging-1.1.0.jar')
    amazonImplementation files('libs/login-with-amazon-sdk.jar')

    androidTestImplementation('com.android.support.test.espresso:espresso-core:3.0.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    testImplementation 'junit:junit:4.12'
}

if (getGradle().getStartParameter().getTaskRequests().toString().contains('Google')) {
    apply plugin: 'com.google.gms.google-services'
} else if (getGradle().getStartParameter().getTaskRequests().toString().contains('Huawei')) {
    apply plugin: 'com.huawei.agconnect'
}


P.S. I have also asked my question at Stackoverflow.

fire tabletsubmission testing certificationamazon device messaginglogin with amazon
10 |5000

Up to 2 attachments (including images) can be used with a maximum of 512.0 KiB each and 1.0 MiB total.

0 Answers